الجمعة، 3 مايو، 2013

Sensing Barometric Pressure BMP085 حساس الضغط الجوي


Sensing Barometric Pressure 


BMP085



اليوم سيكون موضوع تدوينتي هو الحساس BMP085 و هو حساس يستخدم  لقراءة الضغط الجوي , و يعتمد على البروتوكول I2C   في  التخاطب مع المتحكم الأصغري . 



يتميز  BMP085  لعدة مزايا منها :
1) يعطي مدى ضغط جوي من (300-1100)hPa أي من( -500, 9000) meter 
2) فولتية تشغيل منخفضة (1.8V-3.6V ).
3)استهلاك متدني للطاقة 
4) له خاصية خطية , تجعل دقة القراءة عالية جداً (0.06hPa) أي تقريباً 0.5  متر ! .
5) الدقة Resolution  عالية جداً (0.03hPa ~ 0.25m )
6) استخدام البروتوكول I2C 
7) منخفض التكلفة مقارنة بأنواع أخرى 

كل هذا المميزات المتوفرة في هذا الحساس , تجعلنا قادرين على التعامل معه من أجل معرفة الضغط الجوي .

السؤال الآن , لماذا يتوجب علينا الضغط الجوي ؟ 
قد يكون له العديد من الأسباب , و أهم سبب أراه شخصياً هو قدرتنا على التنبؤ بالحالة الجوية , لذلك نسمع غالباً المتنبئ الجوي يذكر الضغط الجوي في كل نشرة جوية " منخفض جوي أو مرتفع جوي " .

حسناً لنلقي نظرة على الحساس  BMP085 من حيث مداخله 


Vcc : هو مدخل التغذية , و يغذى من مصدر 3.3 فولت من بطاقة الأردوينو , تذكر أن لا تغذي هذا الحساس من مصدر أكبر من 3.6 فولت لأنه سيتسبب بتخريبه .

SDA: هو مربط البيانات في الحساس , و تنتقل عبره البيانات من و إلى المتحكم , و بما أننا نتحدث عن البروتوكول I2C لذلك يوصل هذا المربط مع الرجل A4 ببطاقة الأردوينو .

SCL: هو دخل الساعة الذي ستتغير الأوامر و البيانات اعتماداً على قدح هذا المربط , و يربط مع الرجل A5 ببطاقة الأردوينو .

Gnd: و هو الأرضي , و يشبك مع سالب مصدر التغذية.

الرجلان المتبقيتان XCLR و EOC هما مدخلي التصفير و انهاء وقت انتظار الأوامر , لن نستعملها هنا .

و التوصيل كما في الشكل ادناه :


this Schematic are taken from Ladyada tutorial which you can find it on this link
http://learn.adafruit.com/bmp085/wiring-the-bmp085
التوصيل سهل , أليس كذلك 

المعدات التي سنحتاجها لإجراء هذه التجربة سهلة جداً .
1) بطاقة اردوينو 
2) الحساس  BMP085 
3) اسلاك توصيل 
4) لوحة تعليمية مثقوبة BreadBoard

البرنامج :

بعد الأنتهاء من توصيل الحساس BMP085 مع بطاقة الأردوينو , سنبدأ بالبرمجة و سأتبع طريقتين بالبرمجة 
1) باستخدام مكتبة wire.h الخاصة بالبروتوكول I2C فقط .
2) باستخدام مكتبة wire.h و مكتبة خاصة لهذا الحساس BMP85.h و أنا أفضلها بالتعامل مع هذا الحساس .

1) باستخدام مكتبة wire.h الخاصة بالبروتوكول I2C فقط .

سيحتوي هذا البرنامج على معادلات رياضية معقدة نوعاً ما , مردها للمعادلة الرياضية التي سنحتاجها لمعالجة إشارة الحساس و التي تساوي :


و كل حد من حدود المعادلة أعلاه هي :


و من النشرة الفنية نعرف أن عنوان هذا الحساس هو 0x77 , هذا العنوان مهم جداً للتواصل بين المتحكم و الحساس .

الكود موجود هنا :

//......................................................................
// this code was written on bilder blog , More information
// http://bildr.org/2011/06/bmp085-arduino/
//Arduino 1.0+ Only
//Arduino 1.0+ Only

/*Based largely on code by  Jim Lindblom

 Get pressure, altitude, and temperature from the BMP085.
 Serial.print it out at 9600 baud to serial monitor.
 */

#include <Wire.h>

#define BMP085_ADDRESS 0x77  // I2C address of BMP085

const unsigned char OSS = 0;  // Oversampling Setting

// Calibration values
int ac1;
int ac2;
int ac3;
unsigned int ac4;
unsigned int ac5;
unsigned int ac6;
int b1;
int b2;
int mb;
int mc;
int md;

// b5 is calculated in bmp085GetTemperature(...), this variable is also used in bmp085GetPressure(...)
// so ...Temperature(...) must be called before ...Pressure(...).
long b5; 

void setup(){
  Serial.begin(9600);
  Wire.begin();

  bmp085Calibration();
}

void loop()
{
  float temperature = bmp085GetTemperature(bmp085ReadUT()); //MUST be called first
  float pressure = bmp085GetPressure(bmp085ReadUP());
  float atm = pressure / 101325; // "standard atmosphere"
  float altitude = calcAltitude(pressure); //Uncompensated caculation - in Meters 

  Serial.print("Temperature: ");
  Serial.print(temperature, 2); //display 2 decimal places
  Serial.println("deg C");

  Serial.print("Pressure: ");
  Serial.print(pressure, 0); //whole number only.
  Serial.println(" Pa");

  Serial.print("Standard Atmosphere: ");
  Serial.println(atm, 4); //display 4 decimal places

  Serial.print("Altitude: ");
  Serial.print(altitude, 2); //display 2 decimal places
  Serial.println(" M");

  Serial.println();//line break

  delay(1000); //wait a second and get values again.
}

// Stores all of the bmp085's calibration values into global variables
// Calibration values are required to calculate temp and pressure
// This function should be called at the beginning of the program
void bmp085Calibration()
{
  ac1 = bmp085ReadInt(0xAA);
  ac2 = bmp085ReadInt(0xAC);
  ac3 = bmp085ReadInt(0xAE);
  ac4 = bmp085ReadInt(0xB0);
  ac5 = bmp085ReadInt(0xB2);
  ac6 = bmp085ReadInt(0xB4);
  b1 = bmp085ReadInt(0xB6);
  b2 = bmp085ReadInt(0xB8);
  mb = bmp085ReadInt(0xBA);
  mc = bmp085ReadInt(0xBC);
  md = bmp085ReadInt(0xBE);
}

// Calculate temperature in deg C
float bmp085GetTemperature(unsigned int ut){
  long x1, x2;

  x1 = (((long)ut - (long)ac6)*(long)ac5) >> 15;
  x2 = ((long)mc << 11)/(x1 + md);
  b5 = x1 + x2;

  float temp = ((b5 + 8)>>4);
  temp = temp /10;

  return temp;
}

// Calculate pressure given up
// calibration values must be known
// b5 is also required so bmp085GetTemperature(...) must be called first.
// Value returned will be pressure in units of Pa.
long bmp085GetPressure(unsigned long up){
  long x1, x2, x3, b3, b6, p;
  unsigned long b4, b7;

  b6 = b5 - 4000;
  // Calculate B3
  x1 = (b2 * (b6 * b6)>>12)>>11;
  x2 = (ac2 * b6)>>11;
  x3 = x1 + x2;
  b3 = (((((long)ac1)*4 + x3)<<OSS) + 2)>>2;

  // Calculate B4
  x1 = (ac3 * b6)>>13;
  x2 = (b1 * ((b6 * b6)>>12))>>16;
  x3 = ((x1 + x2) + 2)>>2;
  b4 = (ac4 * (unsigned long)(x3 + 32768))>>15;

  b7 = ((unsigned long)(up - b3) * (50000>>OSS));
  if (b7 < 0x80000000)
    p = (b7<<1)/b4;
  else
    p = (b7/b4)<<1;

  x1 = (p>>8) * (p>>8);
  x1 = (x1 * 3038)>>16;
  x2 = (-7357 * p)>>16;
  p += (x1 + x2 + 3791)>>4;

  long temp = p;
  return temp;
}

// Read 1 byte from the BMP085 at 'address'
char bmp085Read(unsigned char address)
{
  unsigned char data;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 1);
  while(!Wire.available())
    ;

  return Wire.read();
}

// Read 2 bytes from the BMP085
// First byte will be from 'address'
// Second byte will be from 'address'+1
int bmp085ReadInt(unsigned char address)
{
  unsigned char msb, lsb;

  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(address);
  Wire.endTransmission();

  Wire.requestFrom(BMP085_ADDRESS, 2);
  while(Wire.available()<2)
    ;
  msb = Wire.read();
  lsb = Wire.read();

  return (int) msb<<8 | lsb;
}

// Read the uncompensated temperature value
unsigned int bmp085ReadUT(){
  unsigned int ut;

  // Write 0x2E into Register 0xF4
  // This requests a temperature reading
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x2E);
  Wire.endTransmission();

  // Wait at least 4.5ms
  delay(5);

  // Read two bytes from registers 0xF6 and 0xF7
  ut = bmp085ReadInt(0xF6);
  return ut;
}

// Read the uncompensated pressure value
unsigned long bmp085ReadUP(){

  unsigned char msb, lsb, xlsb;
  unsigned long up = 0;

  // Write 0x34+(OSS<<6) into register 0xF4
  // Request a pressure reading w/ oversampling setting
  Wire.beginTransmission(BMP085_ADDRESS);
  Wire.write(0xF4);
  Wire.write(0x34 + (OSS<<6));
  Wire.endTransmission();

  // Wait for conversion, delay time dependent on OSS
  delay(2 + (3<<OSS));

  // Read register 0xF6 (MSB), 0xF7 (LSB), and 0xF8 (XLSB)
  msb = bmp085Read(0xF6);
  lsb = bmp085Read(0xF7);
  xlsb = bmp085Read(0xF8);

  up = (((unsigned long) msb << 16) | ((unsigned long) lsb << 8) | (unsigned long) xlsb) >> (8-OSS);

  return up;
}

void writeRegister(int deviceAddress, byte address, byte val) {
  Wire.beginTransmission(deviceAddress); // start transmission to device 
  Wire.write(address);       // send register address
  Wire.write(val);         // send value to write
  Wire.endTransmission();     // end transmission
}

int readRegister(int deviceAddress, byte address){

  int v;
  Wire.beginTransmission(deviceAddress);
  Wire.write(address); // register to read
  Wire.endTransmission();

  Wire.requestFrom(deviceAddress, 1); // read a byte

  while(!Wire.available()) {
    // waiting
  }

  v = Wire.read();
  return v;
}

float calcAltitude(float pressure){

  float A = pressure/101325;
  float B = 1/5.25588;
  float C = pow(A,B);
  C = 1 - C;
  C = C /0.0000225577;

  return C;
}






البرنامج كبير و صعب شرحه لغير المحترفين بالبرمجة و لغير المطلع على النشرة الفنية الخاصة بهذا الحساس , على العموم هذا البرنامج يقوم بقراءة الضغط الجوي و يقيس الأرتفاع اعتماداً على هذا المنحنى الذي يبين العلاقة بين الضغط و الأرتفاع 



كل فكرة البرنامج هي عمل معايرة لقيم الحرارة و الضغط المأخوذة من الحساس و أدخالها في جملة المعايرة و القيام بالعمليات الحسابية اللازمة لأخذ القيمة النهائية .

حسناً لننتقل للجزء الثاني . 

2) باستخدام مكتبة wire.h و مكتبة خاصة لهذا الحساس 

قم بتحميل المكتبة من هذا الرابط Library Download  و قم بتحميل المكتبة كملف مضغوط x.zip "ستجده اعلى يسار الشاشة" ثم قم بفك الضغط و وضع المكتبة في مسار المكتبات داخل ملف الأردوينو " تأكد من أن اسم المجلد الذي ستضعه هو(Adafruit_BMP085 ) لانه غير ذلك لن تعمل المكتبة !" و شغل البرنامج الذي يأتي كمثال مع المكتبة .




أو يمكنك أن تستخدم هذا البرنامج :


#include "Wire.h"
#include "Adafruit_BMP085.h"

Adafruit_BMP085 bmp;

void setup() {
  Serial.begin(9600);
  bmp.begin();  
}

void loop() {
    Serial.print("Temperature = ");
    Serial.print(bmp.readTemperature());
    Serial.println(" *C");

    Serial.print("Pressure = ");
    Serial.print(bmp.readPressure());
    Serial.println(" Pa");

    Serial.println();
    delay(500);
}

سأنهي التدوينة بتوضيح الآتي ,عند تطبيق البرنامج و رغبتنا في معرفة الأرتفاع الذي نتواجد عليه الآن , يمكننا أضافة أمر لقراءة الأرتفاع لكنه في بادئ الأمر سيعطي خطأ واضحاً في القراءة , فما سبب ذلك ؟
 يختلف الموقع altitude بالنسبة للضغط , لأعتماد ذلك على درجة الحرارة "أو حالة الطقس"  , الضغط عند مستوى سطح البحر متغير أعتماداً على تغير الطقس , إذن ما العمل ؟

 البرنامج الموجود مع المكتبة يعطي الموقع الدقيق الذي أنت فيه إذا تم ضبط قيمة الضغط الجوي لسطح البحر داخل البرنامج .

يتم ذلك داخل الأمر 




القيمة التي نضعها بين قوسين يمكن أخذها من أي موقع متخصص بالحالة الجوية على الأنترنت , أنا أخذت القيمة من هذا الموقع   
ما ستحتاجه هو قيمة الضغط الجوي عند سطح البحر في هذه اللحظة 


و هذه القيمة تساوي 101200Pa , نعوضها داخل القوس , فتظهر النتيجة أقرب للصحة .

أتمنى أن يكون ما قدمته اليوم مفيداً و شيقاً و أنتظر تعليقاتكم و مشاركاتكم حول الموضوع 

تحياتي 

0 التعليقات :

إرسال تعليق

 
Creative Commons License
This work is licensed under a Creative Commons Attribution-NonCommercial-ShareAlike 4.0 International License.